Imatge:Fighting lightsabres.jpg
De Viquip??dia
No hi ha una versi?? amb una resoluci?? m??s gran.
Fighting_lightsabres.jpg??? (512 ?? 384 p??xels, mida de l'arxiu: 38 KB, tipus MIME: image/jpeg)
 | Aquest arxiu ??s una c??rrega compartida, extreta del projecte Wikimedia Commons i pot ser usada per altres projectes. Si voleu disposar de m??s informaci?? sobre el fitxer, podeu visitar la p??gina original |
[edit] Information about the image
| Description |
Dansk: Tegning af et bl??t og r??dt lyssv??rd, der f??gter. Kan bruges som et ikon.
English: Drawing of a blue and red lightsaber fighting. Can be used as an icon.
|
|---|---|
| Source |
This is own work. The image is based on Image:Lsbleu.jpg, which is in the public domain, and created using Adobe Photoshop CS. |
| Date |
2006-10-19 |
| Author |
S??ren Peo Pedersen, from a design originally by Bjarke Walling |
| Permission (Reusing this image) |
Based on image in the public domain. |
| Other versions | Image:Lsbleu.jpg Image:Dueling lightsabers.svg |
[edit] Licensing
[edit] POV-Ray code
Peo's version is made using the Persistence of Vision Raytracer, or "POV-Ray" for short. Use the code below to have this program render this image in any desired size/resolution:
global_settings {max_trace_level 10}
#declare HandleMetal=texture {pigment {color rgb .5} // Metal for end
finish {ambient .4 reflection .6 phong 1 metallic} // parts of handle
}
#macro Saber(BeamColor) // Renders one saber with specified beam color
union {
// Parts forming the handle:
cone {<0,-4,0>,.05,<0,-3.9,0>,.17 texture {HandleMetal}}
cylinder {<0,-3.9,0>,<0,-3.85,0>,.17 texture {HandleMetal}}
cone {<0,-3.85,0>,.17,<0,-3.83,0>,.15 texture {HandleMetal}}
cylinder {<0,-3.83,0>,<0,-2.3,0>,.15 pigment {color rgb .5} finish {ambient .4}}
cone {<0,-2.3,0>,.17,<0,-2.28,0>,.15 open texture {HandleMetal}}
cylinder {<0,-2.28,0>,<0,-2.26,0>,.17 open texture {HandleMetal}}
cone {<0,-2.26,0>,.17,<0,-2.01,0>,.1 open texture {HandleMetal}}
// The beam:
cylinder {<0,-2,0>,<0,4,0>,1
pigment {color rgbt 1}
hollow
interior {
media {
intervals 10 samples 10,100 confidence 0.9 // Settings re-
variance 1.0/128 ratio 0.9 // garding the "glowing" beam
absorption rgb <1,1,1>-BeamColor
method 3
density {
cylindrical
density_map { // Density: Most dense along
[0 color rgb 0] // the axis, or "center", of
[.4 color rgb .0625] // the beam; fading off at
[.5 color rgb .125] // greater distances from the
[.6 color rgb .25] // beam.
[.7 color rgb .5]
[.8 color rgb 1]
[.9 color rgb 2]
[1 color rgb 10]
} // End of density_map
} // End of density
} // End of media
} //end of interior
} //end of "beam" cylinder
} // End of entire saber definition:
#end
#declare Spotty=pigment { // Pattern for "spotty
bumps // surroundings", to
color_map { // make metals look
[0 color rgb 0] // "really metallic".
[1 color rgb 1]
}
scale .3
}
sky_sphere {pigment { // Combine spotty pattern
gradient z // with a neutral, white
pigment_map { // background for the a-
[0 Spotty] // rea the camera "sees".
[.884 Spotty]
[.884 color rgb 1]
[1 color rgb 1]
}
translate -.5
scale 2
}}
#object {Saber(<1,.3,.1>) rotate <0,0,-53>}
#object {Saber(<.1,.3,1>) rotate <0,0,53>}
camera {
location <0,0,-5.5>
look_at 0
}
light_source {<-100,200,-150> color rgb 1}
light_source {<200,150,100> color rgb 1}
Historial del fitxer
Cliqueu sobre la data/hora per veure el fitxer tal com era aleshores.
| Data/Hora | Dimensions | Usuari | Comentari | |
|---|---|---|---|---|
| actual | 01:02, 6 nov 2006 | 512??384 (38 KB) | Peo | (New and improved, as requested by Bjarne Wallin -- info, POV-code and more coming up.) |
| 00:03, 19 oct 2006 | 800??630 (38 KB) | Walling |
Enlla??os a la imatge
Les seg??ents p??gines enllacen a aquesta imatge:
